Build Script Sample

groovy

//file:noinspection GroovyAssignabilityCheck

apply from: rootProject.file("gradle/dependencies.gradle")

allprojects {
    buildscript {
        repositories {
            pullRepositories.each { repository -> maven repository }
            mavenCentral {
                content {
                    excludeGroup "org.tts.coding"
                }
            }
        }
    }

    apply plugin: "idea"

    group = "org.tts.coding"
    version = "1.0.0"

    repositories {
        pullRepositories.each { repository -> maven repository }
        mavenCentral {
            content {
                excludeGroup "org.tts.coding"
            }
        }
    }

    idea {
        module {
            inheritOutputDirs = false
            outputDir = project.file("out/production")
            testOutputDir = project.file("out/test")
            downloadSources = true
            downloadJavadoc = false
        }
    }

    /* 清空build缓存 */
    task clear(type: Delete) {
        delete "${projectDir}/build"
        delete "${projectDir}/out"
    }
}

subprojects { project ->
    apply plugin: "java"
    apply plugin: "java-library"

    compileJava {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
        options.encoding = "UTF-8"
    }

    dependencies {
        testImplementation libs.junit
        annotationProcessor libs.lombok
        compileOnly libs.lombok
        testAnnotationProcessor libs.lombok
        testCompileOnly libs.lombok
        /* spring BOM */
        implementation libs.spring
    }
}

kotlin