Skip to main content

Settings Script Sample

groovy​

pluginManagement {
    repositories {
        maven {
            name = "aliyun-gradle-plugin"
            url = "https://maven.aliyun.com/repository/gradle-plugin"
            content {
                excludeGroup "org.tts.coding"
            }
        }
        gradlePluginPortal {
            content {
                excludeGroup "org.tts.coding"
            }
        }
        maven {
            name = "nexus-release"
            url = "https://packages.aliyun.com/maven/repository/2109469-release-ORaPIw/"
            credentials {
                username = "${maven_release_username}"
                password = "${maven_release_password}"
            }
            content {
                includeGroup "org.tts.coding"
            }
            mavenContent {
                releasesOnly()
            }
        }
        maven {
            name = "nexus-snapshot"
            url = "https://packages.aliyun.com/maven/repository/2109469-snapshot-Vq6lEd/"
            credentials {
                username = "${maven_snapshot_username}"
                password = "${maven_snapshot_password}"
            }
            content {
                includeGroup "org.tts.coding"
            }
            mavenContent {
                snapshotsOnly()
            }
        }
    }
}

rootProject.name = "tts-coding"
rootProject.buildFileName = "tts-coding.gradle"

include("module-1", "module-2")

rootProject.children.each { project -> setBuildFileName(project) }

/**
 * 设置项目构建文件名
 * @param projectDescriptor
 */
def setBuildFileName(ProjectDescriptor projectDescriptor) {
    projectDescriptor.buildFileName = "${projectDescriptor.name}.gradle"
    Set<ProjectDescriptor> children = projectDescriptor.getChildren()
    if (null != children && !children.isEmpty()) {
        children.forEach { child -> setBuildFileName(child) }
    }
}

kotlin​

``