maven 仓库声明

注意

私服仓库密码可在用户全局 gradle.properties 配置文件中配置。

pluginManagement

repositories {
    maven {
        name = "aliyun-maven"
        url = "https://maven.aliyun.com/nexus/content/groups/public/"
        content {
            excludeGroup "org.tts.coding"
        }
    }
    mavenCentral {
        content {
            excludeGroup "org.tts.coding"
        }
    }
    gradlePluginPortal {
        content {
            excludeGroup "org.tts.coding"
        }
    }
    maven {
        name = "nexus-release"
        url = "https://packages.aliyun.com/maven/repository/2109469-release-ORaPIw/"
        credentials {
            username = "${maven_release_username}"
            password = "${maven_release_password}"
        }
        content {
            includeGroup "org.tts.coding"
        }
        mavenContent {
            releasesOnly()
        }
    }
    maven {
        name = "nexus-snapshot"
        url = "https://packages.aliyun.com/maven/repository/2109469-snapshot-Vq6lEd/"
        credentials {
            username = "${maven_snapshot_username}"
            password = "${maven_snapshot_password}"
        }
        content {
            includeGroup "org.tts.coding"
        }
        mavenContent {
            snapshotsOnly()
        }
    }
}

依赖拉取仓库

/* maven 拉取仓库 */
ext.pullRepositories = [
    {
        name = "aliyun-maven"
        url = "https://maven.aliyun.com/nexus/content/groups/public/"
        content {
            excludeGroup "org.tts.coding"
        }
    },
    {
        name = "nexus-release"
        url = "https://packages.aliyun.com/maven/repository/2109469-release-ORaPIw/"
        credentials {
            username = "${maven_release_username}"
            password = "${maven_release_password}"
        }
        content {
            includeGroup "org.tts.coding"
        }
        mavenContent {
            releasesOnly()
        }
    },
    {
        name = "nexus-snapshot"
        url = "https://packages.aliyun.com/maven/repository/2109469-snapshot-Vq6lEd/"
        credentials {
            username = "${maven_snapshot_username}"
            password = "${maven_snapshot_password}"
        }
        content {
            includeGroup "org.tts.coding"
        }
        mavenContent {
            snapshotsOnly()
        }
    }
]

注意

拉取仓库需将 mavenCentral 仓库加上，配置参考 pluginManagement -> repositories 部分。

依赖发布仓库

/* maven 推送仓库 */
ext.pushRepositories = [
    snapshot: [
        {
            name = "nexus-snapshot"
            url = "https://packages.aliyun.com/maven/repository/2109469-snapshot-Vq6lEd/"
            credentials {
                username = "${maven_snapshot_username}"
                password = "${maven_snapshot_password}"
            }
        }
    ],
    relsease: [
        {
            name = "nexus-release"
            url = "https://packages.aliyun.com/maven/repository/2109469-release-ORaPIw/"
            credentials {
                username = "${maven_release_username}"
                password = "${maven_release_password}"
            }
        }
    ]
]

配置项目的拉取仓库

allprojects {
    buildscript {
        repositories {
            pullRepositories.each { repository -> maven repository }
            mavenCentral {
                content {
                    excludeGroup "org.tts.coding"
                }
            }
        }
    }
    repositories {
        pullRepositories.each { repository -> maven repository }
        mavenCentral {
            content {
                excludeGroup "org.tts.coding"
            }
        }
    }
    ......    
}

配置项目的发布仓库

提示

发布仓库配置请参考 发布仓库配置。